1 REM *** QUIZ MAKER ***
2 REM USE THIS TO GENERATE QUIZ DATA FILES FOR "THE MOST AND THE LEAST"
3 REM (IN DIRECT MODE, TYPE 'POKE 53265,PEEK(53265)OR 64' TO MAKE SHIFTED
4 REM CHARACTERS SHOW UP WHEN TYPING THEM IN
8 REM ** OPEN QUIZ FILE
9 REM * CHANGE THE NAME FOR EACH NEW QUIZ FILE YOU CREATE
10 FF$="QUIZ MATRIX"
11 FF$="@0:Q "+LEFT$(FF$,14)+",S,W"
12 OPEN 2,8,2,FF$
14 REM * PREPARE CARRIAGE RETURN VARIABLE
15 Z$=CHR$(13)
16 REM * SELECT EXTENDED BACKGROUND COLOR MODE
17 POKE 53265,PEEK(53265)OR 64
18 REM ** READ QUIZ DATA AND PRINT IT TO FILE
19 REM * HOW MANY QUIZZES?
20 NQ=2:PRINT#2,NQ
28 REM ** MAIN LOOP FOR ALL QUIZZES **
29 REM * READ TOTAL NUMBER OF ENTRIES IN THIS QUIZ
30 FOR I=1 TO NQ:READ TN:PRINT#2,TN
31 REM * COLORS FOR BACKGROUNDS 0-3
32 FOR J=0 TO 3:READ A:PRINT#2,A:POKE 53281+J,A:NEXT:POKE 53280,PEEK(53281)
33 REM * COLORS FOR FOREGROUNDS 0-3
34 FOR J=0 TO 3:READ FC$(J):PRINT#2,FC$(J):NEXT
35 REM * QUIZ TITLE LINE & FORMAT/INSTRUCTION LINE
36 READ A$,B$:A$=FC$(3)+A$:B$=FC$(0)+B$:PRINT#2,A$Z$B$:PRINT"[147]"A$:PRINT B$
37 REM * COLUMN HEADERS
38 READ A$,B$:A$=FC$(1)+A$:B$=FC$(1)+B$:PRINT#2,A$Z$B$:PRINT A$B$
39 REM ** LOOP FOR EACH QUIZ **
40 FOR J=1 TO TN
41 REM * GET ENTRY & FACT (1ST ENTRY=HEADINGS, NOT COUNTED IN TOTAL NUMBER)
42 READ A$,B$:C$="":A$=" "+A$:FOR K=1 TO LEN(B$):A=ASC(MID$(B$,K,1))
43 REM * CONVERT FACT TO SHIFTED/REVERSED CHARACTERS
44 IF A<32 OR A>95 THEN A=160:GOTO 47
45 IF A>63 THEN A=A+32:GOTO 47
46 A=A+128
47 C$=C$+CHR$(A):NEXT:B$="[160]"+C$+"[146]"
48 REM * PRINT STRINGS TO SCREEN AND FILE FF$
49 PRINT#2,A$Z$B$:PRINT ""FC$(2)A$"[146]"FC$(3)B$:NEXT:NEXT
50 CLOSE 2:PRINT "";:END
97 REM *** DATA FOR QUIZZES ***
98 REM ** QUIZ #1
99 REM * NUMBER OF ENTRIES, SCREEN COLORS, FOREGROUND COLORS
100 DATA 10,0,4,7,8,"[154]","[144]","[154]",""
101 REM * QUIZ TITLE (INCLUDE 39 SHIFTED CHARACTERS, PLUS REVERSE ON/OFF)
102 DATA "[160][160][160][160][160][160][160][160][160][160][160][160][198][201][210][211][212][160][212][197][211][212][160][209][213][201][218][160][160][160][160][160][160][160][160][160][160][160][160][146]"
103 REM * FORMAT/INFORMATION LINE (39 UNSHIFTED CHARACTERS, NOT REVERSED)
104 DATA "    JUST SO YOU CAN SEE HOW IT WORKS   "
105 REM * COLUMN HEADER FOR ENTRIES (21 SHIFTED CHARACTERS)
106 DATA "[160][211][193][205][208][204][197][160][197][206][212][210][201][197][211][160][160][160][160][160][160]"
107 REM * COLUMN HEADER FOR FACTS (18 SHIFTED CHARACTERS)
108 DATA "[160][211][193][205][208][204][197][160][198][193][195][212][211][160][160][160][160][160]"
109 REM ** QUIZ ITEMS IN CORRECT ORDER (20 CHAR./ENTRY, 17 SHIFTED CHAR./FACT)
110 DATA "ENTRY #1            ","FASCINATING FACT!"
111 DATA "ENTRY #2            ","FASCINATING FACT!"
112 DATA "ENTRY #3            ","FASCINATING FACT!"
113 DATA "ENTRY #4            ","FASCINATING FACT!"
114 DATA "ENTRY #5            ","FASCINATING FACT!"
115 DATA "ENTRY #6            ","FASCINATING FACT!"
116 DATA "ENTRY #7            ","FASCINATING FACT!"
117 DATA "ENTRY #8            ","FASCINATING FACT!"
118 DATA "ENTRY #9            ","FASCINATING FACT!"
119 DATA "ENTRY #10           ","FASCINATING FACT!"
198 REM ** QUIZ #2 (JUST A SAMPLE)
199 REM * NUMBER OF ENTRIES, SCREEN COLORS, FOREGROUND COLORS
200 DATA 20,14,7,4,8,"","[144]","[144]",""
201 REM * QUIZ TITLE (INCLUDE 39 SHIFTED CHARACTERS, PLUS REVERSE ON/OFF)
202 DATA "[160][160][160][160][160][160][160][160][160][208][204][193][195][197][211][160][215][197][160][200][193][214][197][160][204][201][214][197][196][160][160][160][160][160][160][160][160][160][160][146]"
203 REM * FORMAT/INFORMATION LINE (39 UNSHIFTED CHARACTERS, NOT REVERSED)
204 DATA " FROM THE EARLIEST TO THE MOST RECENT  "
205 REM * COLUMN HEADER FOR ENTRIES (21 SHIFTED CHARACTERS)
206 DATA "[160][211][212][210][197][197][212][160][193][196][196][210][197][211][211][160][160][160][160][160][160]"
207 REM * COLUMN HEADER FOR FACTS (18 SHIFTED CHARACTERS)
208 DATA "[160][195][201][212][217][160][193][206][196][160][211][212][193][212][197][160][160][160]"
209 REM ** QUIZ ITEMS IN CORRECT ORDER (20 CHAR. PER ENTRY, 17 CHAR. PER FACT)
210 DATA "975 LAS PALMAS DRIVE","SANTA CLARA^ CA  "
211 DATA "1425 E. DOVER STREET","MESA^ AZ         "
212 DATA "31 'L' STREET       ","SALT LAKE CITY^UT"
213 DATA "117 'J' STREET      ","SALT LAKE CITY^UT"
214 DATA "598 HIGH RIDGE ROAD ","SANDY^ UT        "
215 DATA "370 SOUTH 650 EAST  ","OREM^ UT         "
216 DATA "2314 MIAMI BLVD.    ","SOUTH BEND^ IN   "
217 DATA "5701 COURTFIELD DR. ","GOSHEN^ IN       "
218 DATA "12 E. FRIENDLY      ","GREENSBORO^ NC   "
219 DATA "BOX 33789^ HWY. 62  ","CASWELL^ NC      "
220 DATA "4704 PENN WYNE DR.  ","GREENVILLE^ SC   "
221 DATA "111 TRADD STREET    ","CHARLESTON^ SC   "
222 DATA "17 MEETING STREET   ","CHARLESTON^ SC   "
223 DATA "1490 SEAVIEW ROAD   ","SULLIVAN'S ISL^SC"
224 DATA "48 GRAMERCY PARK SO.","NEW YORK CITY^ NY"
225 DATA "599 PARK AVENUE     ","NEW YORK CITY^ NY"
226 DATA "MIDGEWAY FARM       ","PEA HOLLOW^ TN   "
227 DATA "47 GRACE COURT      ","CHEVY CHASE^ MD  "
228 DATA "990 NORTH TALLICK   ","SILVER SPRING^ MD"
229 DATA "12 SADDLEBACK TRACE ","BUCKLE RIDGE^ WV "
230 REM THIS IS THE MAXIMUM NUMBER OF ENTRIES POSSIBLE IN ANY QUIZ
231 REM NOTICE THAT THE ^ CHARACTER IS USED FOR COMMAS WITHIN ENTRIES.
232 REM 'THE LEAST AND THE MOST' CHANGES THIS TO A COMMA WITH CUSTOM CHARACTERS